jacoco-report-aggregation を使ってマルチモジュール構成のカバレッジレポートを集める

tasks.register<JacocoReport>("codeCoverageReport") {
    subprojects {
        val subproject = this
        subproject.plugins.withType<JacocoPlugin>().configureEach {
            subproject.tasks.matching({ it.extensions.findByType<JacocoTaskExtension>() != null }).configureEach {
                val testTask = this
                sourceSets(subproject.sourceSets.main.get())
                executionData(testTask)
            }

            subproject.tasks.matching({ it.extensions.findByType<JacocoTaskExtension>() != null }).forEach {
                rootProject.tasks["codeCoverageReport"].dependsOn(it)
            }
        }
    }
}

plugins {
	// ...
    // ...
	id("jacoco-report-aggregation")
}

subprojects {
    // ...
    // ...

    // モジュール自体には jacoco のプラグインが設定されていることが前提のよう
    // 個別に設定するのは面倒なので、全てのサブプロジェクトで設定したかった
    apply(plugin = "jacoco")

    jacoco {
		toolVersion = "0.8.7"
	}

    // この設定が必要とはドキュメントに書かれていたが、
    // 自分の場合は最初からここ設定してたので差分はわからない
    tasks.withType<Test> {
		useJUnitPlatform()
	}
}

// エントリーポイントとなるモジュールをここに列挙する
// 依存するモジュールは全て自動で解決してくれるみたい
// e.g. module1 -> shared となっている場合には以下の設定で shared も対象に含まれる
dependencies {
	jacocoAggregation(project(":module1"))
	jacocoAggregation(project(":module2"))
    jacocoAggregation(project(":module3"))
    // ...
}

// カバレッジレポートの対象を自分達で書いてるアプリケーションコードに限定したい
tasks {
	testCodeCoverageReport {
		classDirectories.setFrom(files(
			subprojects.map {it.fileTree(mapOf("dir" to "${it.buildDir}/classes/kotlin/main"))}
		))
	}
}